/* HeuristicLab
 * Copyright (C) 2002-2013 Heuristic and Evolutionary Algorithms Laboratory (HEAL)
 *
 * This file is part of HeuristicLab.
 *
 * HeuristicLab is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * HeuristicLab is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with HeuristicLab. If not, see <http://www.gnu.org/licenses/>.
 */

// Coco/R grammar for the GPDL compiler

$namespace=HeuristicLab.Problems.GPDL

using System.Text;
using System.Collections.Generic;
using System.Linq;
using IEnumerableConstraintNode = System.Collections.Generic.IEnumerable<ConstraintNode>;

COMPILER GPDef
public GPDefNode AbstractSyntaxTree { get; private set; }

CHARACTERS
  letter = 'A'..'Z' + 'a'..'z'.
  digit = '0'..'9'.

TOKENS
  ident = letter {letter | digit}  .

COMMENTS FROM "/*" TO "*/" NESTED
COMMENTS FROM "//" TO "\r"

IGNORE '\t' + '\r' + '\n'


PRODUCTIONS

  SourceCode<out string src> =                                                    (. src = ""; .)
   "<<"                                                                           (. int beg = la.pos; .)
   {ANY}                                                                          (. int end = la.pos; .)
   ">>"                                                                           (. if(end>beg) src = scanner.buffer.GetString(beg, end); .)
  .

  GPDef =                                                                         (.
                                                                                    RuleNode ruleNode = null;
                                                                                    GPDefNode gpDef = new GPDefNode();
                                                                                    NonTerminalNode ntNode = null;
                                                                                    FitnessFunctionNode fitnessFunNode = null;
                                                                                    TerminalNode tNode = null;
                                                                                    string src = "";
                                                                                  .)
    "PROBLEM" ident                                                               (. gpDef.Name = t.val; .)
    ["CODE" SourceCode<out src>                                                   (. gpDef.ClassCodeNode = new CodeNode{SrcCode = src}; .)
    ]
    ["INIT" SourceCode<out src>                                                   (. gpDef.InitCodeNode = new CodeNode{SrcCode = src}; .)
    ]

    "NONTERMINALS" { NonterminalDecl<out ntNode>                                  (. if(gpDef.IsSymbolDefined(ntNode)) {
                                                                                       SemErr("Duplicate non-terminal symbol: " + ntNode.Ident);
                                                                                     } else {
                                                                                       gpDef.NonTerminals.Add(ntNode);
                                                                                     } 
                                                                                  .)
    }                                                                             (. if(!gpDef.NonTerminals.Any())
                                                                                       SemErr("No non-terminal symbols defined.");
                                                                                  .)
    "TERMINALS" { TerminalDecl<out tNode>                                         (. if(gpDef.IsSymbolDefined(tNode)) {
                                                                                       SemErr("Duplicate terminal symbol: " + tNode.Ident);
                                                                                     } else {
                                                                                       gpDef.Terminals.Add(tNode); 
                                                                                     }
                                                                                  .)
    }                                                                             (. if(!gpDef.Terminals.Any())
                                                                                       SemErr("No terminal symbols defined.");
                                                                                  .)
    "RULES" { RuleDef<out ruleNode>                                               (. 
                                                                                     if(!gpDef.IsNonTerminalDefined(ruleNode.NtSymbol)) {
                                                                                       SemErr("Non-terminal symbol " + ruleNode.NtSymbol + " is not defined in the NONTERMINALS section.");
                                                                                     } else if(gpDef.IsRuleDefined(ruleNode)) {
                                                                                       SemErr("Duplicate rule definition for non-terminal symbol " + ruleNode.NtSymbol);
                                                                                     } else {
                                                                                       gpDef.Rules.Add(ruleNode);
                                                                                     } 
                                                                                   .)
    }                                                                             (.
                                                                                     var undefinedNT = gpDef.UndefinedNonTerminals();
                                                                                     if(!string.IsNullOrEmpty(undefinedNT)) {
                                                                                       SemErr("Rules missing in the RULES section for: " + undefinedNT);
                                                                                     }
                                                                                  .)
                                                                                  (. fitnessFunNode = new FitnessFunctionNode();
                                                                                     gpDef.FitnessFunctionNode = fitnessFunNode;
                                                                                  .)
    ("MAXIMIZE"                                                                   (. fitnessFunNode.Maximization = true; .)
    | "MINIMIZE"                                                                  (. fitnessFunNode.Maximization = false; .)
    )
     SourceCode<out src>                                                          (. fitnessFunNode.SrcCode = src; .)
                                                                                  (. if(errors.count > 0) throw new FatalError("Syntactic or semantic errors found."); .)
    "END" ident                                                                   (.
                                                                                    AbstractSyntaxTree = gpDef;
                                                                                  .)
    '.'
  .


  /******************************************************/
  SemAction<out RuleActionNode action> =                                          (. RuleActionNode myAction = null; action = null; string src = ""; .)
    "SEM" SourceCode<out src>                                                     (.
                                                                                    myAction = new RuleActionNode();
                                                                                    myAction.SrcCode = src;
                                                                                    action = myAction;
                                                                                  .)
  .

  /******************************************************/
  NonterminalDecl<out NonTerminalNode ntNode> =                                   (. string identStr = ""; ntNode = null; string src = ""; .)
    ident                                                                         (. identStr = t.val; .)
    [ SourceCode<out src> ]                                                       (.
                                                                                    var myNtNode = new NonTerminalNode();
                                                                                    ntNode = myNtNode;
                                                                                    myNtNode.Ident = identStr;
                                                                                    myNtNode.FormalParameters = src;
                                                                                  .)
    '.'
  .

  /******************************************************/
  TerminalDecl<out TerminalNode tNode> =                                          (.
                                                                                    string identStr = "";
                                                                                    tNode = null;
                                                                                    TerminalNode myTNode = null;
                                                                                    IEnumerableConstraintNode constraints = new List<ConstraintNode>();
                                                                                    string src = "";
                                                                                  .)
  ident                                                                           (. identStr = t.val; .) 
  [ SourceCode<out src> ]                                                         (.
                                                                                         myTNode = new TerminalNode();
                                                                                         tNode = myTNode;
                                                                                         myTNode.Ident = identStr;
                                                                                         myTNode.FormalParameters = src;
                                                                                         myTNode.FieldDefinitions = Util.ExtractParameters(src);
                                                                                  .)
  [ "CONSTRAINTS" ConstraintDef<out constraints>
  ]                                                                               (. myTNode.Constraints = constraints; .)
  '.'
  .


  /******************************************************/
  ConstraintDef<out IEnumerableConstraintNode constraints>  =                   (.
                                                                                    List<ConstraintNode> constraintsList = new List<ConstraintNode>();
                                                                                    ConstraintNode n = null;
                                                                                    constraints = null;
                                                                                  .)
    { ConstraintRule<out n>                                                       (. constraintsList.Add(n); .)
    }
                                                                                  (. constraints = constraintsList; .)
  .

  /******************************************************/
  ConstraintRule<out ConstraintNode constraint> =                                 (.
                                                                                    constraint = null;
                                                                                  .)
    ident                                                                         (. constraint = new ConstraintNode(t.val); .)
    "IN" SetDefinition<constraint>                                               
  .

  /******************************************************/
  SetDefinition<ConstraintNode constraint> =                                      (. string src = ""; .)
    ("SET"                                                                        (. constraint.Type = ConstraintNodeType.Set; .)
     SourceCode<out src>                                                          (. constraint.SetExpression = src; .)
     |
     "RANGE"                                                                      (. constraint.Type = ConstraintNodeType.Range; .)
     SourceCode<out src>                                                          (. constraint.RangeMinExpression = src; .)
     ".." SourceCode<out src>                                                     (. constraint.RangeMaxExpression = src; .)
    )
  .

  /******************************************************/
  RuleDef<out RuleNode rule> =                                                    (.
                                                                                     AlternativesNode alternatives = null;
                                                                                     string identStr = null;
                                                                                     RuleNode myRule = null;
                                                                                     rule = null;
                                                                                     string src = "";
                                                                                  .)
  ident                                                                           (. identStr = t.val; .) 
  [ SourceCode<out src> ] '='                                                     (.
                                                                                     myRule = new RuleNode();
                                                                                     rule = myRule;
                                                                                     myRule.NtSymbol = identStr;
                                                                                  .)
  ["LOCAL" SourceCode<out src>                                                    (.
                                                                                     myRule.LocalCode = src;
                                                                                  .)
  ]
  SynExpr<out alternatives> '.'                                                  (.
                                                                                    myRule.Alternatives = alternatives;
                                                                                 .)
  .

  /******************************************************/
  SynExpr<out AlternativesNode alt > =                                            (.
                                                                                    alt = new AlternativesNode();
                                                                                    SequenceNode seq = null;
                                                                                  .)
  SynTerm<out seq>                                                                (. 
                                                                                    alt.Add(seq);
                                                                                  .)
  {
    '|' SynTerm<out seq>                                                          (. alt.Add(seq); .)
  }
  .

  /******************************************************/
  SynTerm<out SequenceNode seq> =                                                (. seq = new SequenceNode(); RuleExprNode expr = null; .)
  SynFact<out expr>                                                              (.
                                                                                   seq.Add(expr);
                                                                                 .)
  {
    SynFact<out expr>                                                            (. seq.Add(expr); .)
  }
  .

  /******************************************************/
  SynFact<out RuleExprNode expr> =                                               (.
                                                                                   string identStr = "";
                                                                                   RuleActionNode action = null;
                                                                                   expr = null;
                                                                                   string src = "";
                                                                                 .)
    (ident                                                                       (. identStr = t.val; .)
     [ SourceCode<out src> ]                                                     (.
                                                                                    var callNode = new CallSymbolNode{Ident = identStr};
                                                                                    callNode.ActualParameter = src;
                                                                                    expr = callNode;
                                                                                 .)
// not implemented   | "EPS" 
// not implemented   | '(' SynExpr<ref rules, mBuilder> ')'
// not implemented   | '[' SynExpr<ref rules, mBuilder> ']'
// not implemented   | '{' SynExpr<ref rules, mBuilder> '}'
     | SemAction<out action>                                                     (. expr = action; .)
    )
  .

END GPDef.