// special adaptation of the one-max problem
// must find maximal number of 1-terminals
// optimal solution = 32, number of solutions 2^32
PROBLEM OneMaxBinary

NONTERMINALS
  S<<out int n>>.
  U<<out int n>>.
  V<<out int n>>.
  W<<out int n>>.
  X<<out int n>>.
  Y<<out int n>>.
  T<<out int n>>.

TERMINALS
  A.
  B.

RULES
  S<<out int n>> =                                LOCAL << int n1, n2; >>
    U<<out n1>> U<<out n2>>                       SEM << n = n1 + n2; >>
  .
  U<<out int n>> =                                LOCAL << int n1, n2; >>
    V<<out n1>> V<<out n2>>                       SEM << n = n1 + n2; >>
  .
  V<<out int n>> =                                LOCAL << int n1, n2; >>
    W<<out n1>> W<<out n2>>                       SEM << n = n1 + n2; >>
  .
  W<<out int n>> =                                LOCAL << int n1, n2; >>
    X<<out n1>> X<<out n2>>                       SEM << n = n1 + n2; >>
  .
  // 2^32 solutions
  X<<out int n>> =                                LOCAL << int n1, n2; >>
    T<<out n1>> T<<out n2>>                       SEM << n = n1 + n2; >>
  .

  // uncomment for 2^64 solutions
  // X<<out int n>> =                                LOCAL << int n1, n2; >>
  //   Y<<out n1>> Y<<out n2>>                       SEM << n = n1 + n2; >>
  // .

  Y<<out int n>> =                                LOCAL << int n1, n2; >>
    T<<out n1>> T<<out n2>>                       SEM << n = n1 + n2; >>
  .

  T<<out int n>> = 
    A                                             SEM << n = 1; >>
    | B                                           SEM << n = 0; >>
  .

MAXIMIZE
  << 
    int n;
    S(out n);
    return (double) n;
  >>
END OneMaxBinary.